You can try with something like this:

--------8<------------8<------------8<------------8<-----------8<-------
// -w300 -h600 +a +kff50 +kc

#include "functions.inc"

camera { right x*30/60 location -z*7.5 look_at 0 angle 35 }
light_source { <10,20,-30>, .5 }

#declare TorchWood =
  texture
  { pigment
    { wood color_map { [0 rgb <.7,.4,.2>][1 rgb <.9,.5,.3>] }
      turbulence .5
    }
    normal
    { wood 1
      turbulence .5
    }
    finish { specular .2 }
    scale <.1,1,.1>
  }

#declare SphericalF = function { pattern { spherical } }
#declare NoiseF =
  function
  { (1-f_noise3d(x*5,y*5,z*5)*.9)*
    (1-f_noise3d(x*15,y*15,z*15)*.4)
  }

#declare Torch =
  union
  { sphere
    { 0,1.2 hollow scale <1,2,1> translate y
      pigment { rgbt 1 }
      interior
      { media
        { emission .5
          density
          { function
            { SphericalF(x,y,z)*
              (NoiseF(x,y-clock*3,z)*(1-clock) +
               NoiseF(x,y-clock*3+3,z)*clock)
            }
            density_map
            { [0 rgb 0]
              [.2 rgb <.8,.4,0>]
              [.21 rgb <1,1,.2>]
              [.5 rgb <1,.9,.8>]
              [1 rgb 1] 
            }
          }
        }
        media
        { emission .5
          density
          { function
            { SphericalF(x,y,z)*
              (NoiseF(x,y*2-clock*3,z)*(1-clock) +
               NoiseF(x,y*2-clock*3+3,z)*clock)
            }
            density_map
            { [0 rgb 0]
              [1 rgb 1] 
            }
          }
          scale <1.2,2,1.2>
          translate y*1.4
        }
      }
      scale <1.5,3,1.5>
      rotate z*-5
      translate <.2,1.2,0>
    }

    cone { -y*4,.15, 0,.25 }
    sphere { 0,.25 }
    texture
    { pigment_pattern
      { gradient y color_map { [0 rgb 0][1 rgb 1] }
        scale 4.25 translate -y*4
      }
      texture_map
      { [.7 TorchWood]
        [.8 pigment { rgb 0 }]
        [.9 pigment { rgb x*.8 } finish { ambient 1 }]
        [1 pigment { rgb <1,.2,.2> } finish { ambient 1 }]
      }
    }
  }
  
object { Torch translate -y*3 }
--------8<------------8<------------8<------------8<-----------8<-------

-- 
plane{-x+y,-1pigment{bozo color_map{[0rgb x][1rgb x+y]}turbulence 1}}
sphere{0,2pigment{rgbt 1}interior{media{emission 1density{spherical
density_map{[0rgb 0][.5rgb<1,.5>][1rgb 1]}turbulence.9}}}scale
<1,1,3>hollow}text{ttf"timrom""Warp".1,0translate<-1,-.1,2>}//  - Warp -

Post a reply to this message